Sitemap | EndNote
Showing results for 
Search instead for 
Do you mean 
Reply
Visitor
Posts: 4
Registered: ‎08-11-2009
0

Re: Converting in-text citations to footnotes/endnotes

Hi Irene,

 

As for your second question (i.e. APA 5th): If you're asking whether the Macro would work for a document ALREADY formatted in APA 5th which you would like to convert to a style using footnotes/endnotes instead of in-text citations (e.g. Chicago A), then the answer is YES!  If it's the other way around, then the macro, unfortunatelly, cannot help.

 

As for your first question:

After copying the macro to the clipboard (Ctrl+C),without the "=====" lines at the begining and the end, go to Word 2007 and follow these steps:

 

1) from the "View" ribbon/tab,click on "Macros", and then choose "View Macros" from the drop down list/menu.

 

2) At the new dialog box/window, click in the Macro Name box, and type something there (doesn't matter what as longs as it is without spaces)

 

3) Click on the "Create" button, at the right hand of the dialog box.

 

4) MS-Word launches the VBA ediotr: 

 

5) On the "New Macro (code)" window, delete the lines stating with "Sub [the name you gave on step 2]()" and Ending with "End Sub"

 

6) Paste the Macro (Ctrl + V)

 

7) Close the "Visual Basic for Application" editor window --> this should return you back to Word.

 

8) Click on the Office button (at the top-left hand corner of the screen), and then click on "Word Options" button

 

9) At the Left hand of the new window, click on "Customize"

 

10) At the Right hand of the screen, from the "choose from commands" box, choose "Macros"

 

11) Under that box, you should be able to see now a list of available Macros, one of them should be: "Normal.NewMacros.intext2footnote." --> click it, and then click on the "Add" button (at the middle of the screen/window)

 

12)  Click on the "Modify" button (under the long box to which you've added your macro)

 

13)  At the new dialog box that is displayed with lots of icons, choose the icon to be displayed on the button that will launch your macro, and then click "OK"

 

14) Click OK again at the word options window --> this should get you back to Word.

 

If all is well, you should be able to see a new button on the Quick Access Toolbar (under the Ribbon) with the icon you've just designated.  Clicking on this button will run the macro (make sure you do this only once you've placed the cursor at the begining of the text.)

 

Hope this helps...

Miriam

Visitor
Posts: 1
Registered: ‎03-31-2010
0

Re: Converting in-text citations to footnotes/endnotes

Wow thank you so much for the clear instructions and the macro.  It totally worked for me (once I realised that a page break was not the same as a section break...) and saved me hours of work manually converting the references!  I am not what one would call an expert user so really helpful to have it broken down stage by stage.  Thanks so much.

New User
Posts: 1
Registered: ‎08-08-2010
0

Re: Converting in-text citations to footnotes/endnotes

All of the above was very clear, but unfortunately didn't work at all.  Any idea of what I could be doing wrong.

Visitor
Posts: 4
Registered: ‎08-11-2009
0

Re: Converting in-text citations to footnotes/endnotes

Hi Phyllis,

Sorry for the long delay in responding to your question...

Chances are that your document has only one section, while the macro's code is written under the (plausible) assumption that you have at least 2 sections (i.e. the second one for endnotes).  If this is not the case (e.g. you use only footnotes), simply create a temporary new section at the end of your document, and then try to run the macro again.  Once done, mark the whole endnotes section (CTRL + A when the cursor is within this section), convert it to footnotes (right-click the marked section, and then, simply delete the white space left behind so that you erase the second section created in the beginning of this process.

Hope this would be of help...

Miriam

New User
Posts: 1
Registered: ‎12-05-2010
0

Re: Converting in-text citations to footnotes/endnotes

Peter, 

 

When I get to the point of  entering the citation in the footnote space generated by the Word note system, can I cut and past the citation (or longer material) into the footnote space? Or, do I have retype that material?  I have a manuscript with scores of endnote/footnotes but all of that material, while separately entered in my manuscript and so would appear in printed format as "Endnotes"  appears to my editor's computer as if were text.

 

The trouble, as you can probably deduce, is that I did not create those 'notes' using the Word auto endnote/footnote application. Instead they were created as separate Word Documents and then I copied and pasted them into each chapter of the manuscript. 

 

I really hope that there's a saving grace to all this.

 

Thanks for any help you can think of. 

 

Ken

New User
Posts: 1
Registered: ‎07-16-2011
0

Re: Converting in-text citations to footnotes/endnotes

could sent me screenshots exactly how you do that because i cant find how really works. Im interesting on converting in text citations to footnote only.

New User
Posts: 1
Registered: ‎10-12-2011
0

Re: Converting in-text citations to footnotes/endnotes

Hi Miriam!

 

I have been working with this macro that you suggested for a while now and can't figure out why it is not working for me. 

 

Here is what I am trying to accomplish:

 

https://docs.google.com/document/d/1DufKpBXTCti1Mq6YOu_IFmLTAWV_H9l4J6NqR5I2HwI/edit?hl=en_US

 

I cannot figure out how to adapt your code to something that will work for our purposes! Can you help? I would rather the notes end up as footnotes than as endnotes, but if I can get the code to work for endnotes, then I can just convert them to footnotes separately. 

 

Let me know ASAP if you think this is possible!

 

Thanks, 

 

Katie

Administrator
Posts: 688
Registered: ‎06-26-2008
0

Re: Converting in-text citations to footnotes/endnotes

Technical Support also has some tools to convert in-text citations to footnotes and footnotes to in-text citations. If you contact Technical Support, we can assist with these conversions:

 

http://www.endnote.com/support/entechform.asp

 

Jason Berman
Technical Sup Rep RS

Thomson Reuters

 

Phone: +1 800-336-4474
thomsonreuters.com

Jason Berman
Technical Sup Rep RS

Clarivate Analytics

Phone: +1 800-336-4474
clarivate.com
New User
Posts: 1
Registered: ‎05-09-2014
0

Re: Converting in-text citations to footnotes/endnotes

Thank you Miriam for your post. Yes, the macro does work.

 

I am not a techie, but I do pay attention to directions in a very detailed manner.  I usually do not give comments online, but I thought I needed to do this because Miriam just saved me a lot of headache and time trying to convert my dissertation manuscript from a format in which I used EndNote X6 to create (with JAMA style), to one which my professor prefers (he prefers the one where you have consecutively numbered citations with MS Word footnotes inserted below each page).

 

Typically, inserting footnotes (using Word footnote features and citations inserted with EndNote software) is an easy task if you start this process from the beginning. It becomes difficult when you want to convert your document (which could run into hundreds of pages) containing citations and references (initially created using only the EndNote software) back into a document with footnotes and bibliography (that is arranged in alphabetical order).

 

I found that the macro may not work if you have page breaks and section breaks within your doument and you run the macro without first modifying it like Miriam suggested (i.e., deleting lines 3-6, second to the last line, and replacing line 7 with the suggested code line). However, if you modify the macro, you do not have to remove your already formatted document before running the macro. Also, remember to grant access to the macro by changing the security settings (for Word 2010, the navigation is file>options>trust center>trust center settings>macro settings>enable all macros) (remeber to change this back to the original setting once you've successfully run the macro).

 

The following directions below was exactly what I followed in order to format from Endnote JAMA (without Word footnote) to Chicago 16th A style with Word footnote.

 

1. Follow the direction given by Miriam in copying the macro below into Word

 

2. run macro

 

3. Go to the end of your document. You will find citations having only roman numerals (this was created by the macro) and the original references from your document.

 

4. Change the citations having only Roman numerals (i.e., i, ii, iii, iv, etc) into Word endnote (i.e., those containing both the Roman numerals and word-form citations following the roman numerals, by changing the style within the Word document to ‘Chicago 16th A’ (meanwhile, I reformatted the Chicago 16th A style to look like JAMA style within the edit section of EndNote X6).

 

5. select (4)(i.e., select all the Word endnotes)

 

6. right click on (5) to change the format before converting the Word endnotes to footnotes. Paragraph: align left, body text, indentation: left 0, right 0, special none; Spacing: before 0, after 10pt, line spacing multiple, at 1.15.  

 

7. select  (6)

 

8. right click (7) and select convert to change the endnotes to footnotes (You will now have a document that have the in-text citations as footnotes on each page. Towards the end of your document, you will have the bibliography arranged alphabetically and references numbered consecutively).

 

I hope this helps others in my shoe trying to change the formatting of their document.

 

 

Sub intext2footnote()
Dim vLastSectionI, vField, i, J
For Each vField In ActiveDocument.Fields
Selection.GoTo What:=wdGoToField, Which:=wdGoToNext, Count:=1, Name:= _
"ADDIN"
Selection.Find.ClearFormatting
With Selection.Find
.Text = "{ }"
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdExtend
Selection.Cut
With ActiveDocument.Bookmarks
.Add Range:=Selection.Range, Name:="temp"
.DefaultSorting = wdSortByName
.ShowHidden = False
End With
Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdExtend
ActiveDocument.Endnotes.Add Range:=Selection.Range, Reference:=""
Selection.Paste
Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:="1"
Selection.Find.ClearFormatting
With Selection.Find
.Text = "{ }"
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.GoTo What:=wdGoToBookmark, Name:="temp"
Selection.Find.ClearFormatting
With Selection.Find
.Text = "{ }"
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.ClearFormatting
With Selection.Find
.Text = "{ }"
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
ActiveDocument.Bookmarks("temp").Delete
With ActiveDocument.Bookmarks
.DefaultSorting = wdSortByName
.ShowHidden = False
End With
Selection.MoveRight Unit:=wdCharacter, Count:=1
Next vField
End Sub

 

 

Highlighted
Contributor
Posts: 47
Registered: ‎04-13-2010
3

Updated Macro for converting in-text citations to footnotes; modify suffix and revert author exclusion settings

[ Edited ]

Hi all ...

 

I needed to convert in-text refs like (Jones 2010:23) or (Peters 2011:19-23) to footnote refs of the format

 

..., p. 23.

..., pp. 19-23.

 

and if the in-text citation does not show the author, then switch author on in the footnote

 

This macro is a modification of the one posted by Miriam way back in 2009 from one created by Shyam Ranganathan.

 

I have removed redundant code (which you get when you record a macro), and added comments so those not too familiar with VBA can see what's happening.

 

You can un-comment the message boxes (just delete ' in 'MsgBox ...) to see what's happening.

 

The code could be improved further, but it works OK ... at least for me (Word 2007, Windows 7).

 

Happy conversions!!!

 

PS: To make this work for Endnotes just change ActiveDocument.Footnotes.Add to ActiveDocument.Endnotes.Add

 

---------------------------------------

Public Sub ConvertIntextToFootnote()

Dim oField As Field
Dim sCode As String
Dim sSuffix As String
Dim sSuffixLeft As String
Dim sSuffixRight As String
Dim pos1 As Long
Dim pos2 As Long

'Loop through all fields in the document


For Each oField In ActiveDocument.Fields

    'Is the field an Endnote field?
    
    If InStr(oField.Code.Text, "EN.CITE") = 0 Then GoTo Bypass:
    
    oField.Select
    
    'Modify the Suffix in the field code ... <Suffix>text</Suffix>, if one exists


    sCode = oField.Code.Text
    'MsgBox sCode
    pos1 = InStr(sCode, "<Suffix>")
    
    If pos1 > 0 Then 'suffix exists, so extract it
    
        sSuffixLeft = Left(sCode, pos1 + 7)
        'MsgBox sSuffixLeft
        pos2 = InStr(sCode, "</Suffix>")
        sSuffixRight = Right(sCode, Len(sCode) - pos2 + 1)
        'MsgBox sSuffixRight
        sSuffix = Mid(sCode, pos1 + 8, pos2 - (pos1 + 8))
        'MsgBox sSuffix
        
        'If no dash, replace : with p. else with  pp.


        If InStr(sSuffix, "-") > 0 Then
            sSuffix = Replace(sSuffix, ":", " pp. ")
        Else
            sSuffix = Replace(sSuffix, ":", " p. ")
        End If
        
        'Add a full stop


        sSuffix = sSuffix + "."
        'MsgBox sSuffix
        
        'Now rebuild the code


        sCode = sSuffixLeft + sSuffix + sSuffixRight


        'Set the new code in the field


        oField.Code.Text = sCode
        'MsgBox oField.Code.Text
        
    End If
    
     'If author is excluded, show the author
        
        If InStr(sCode, "ExcludeAuth=""1""") > 0 Then
        
            oField.Code.Text = Replace(sCode, "ExcludeAuth=""1""", "")
            
        End If
    
    Selection.Cut
    
    'Add temporary bookmark so we can return to the Main Story


    With ActiveDocument.Bookmarks
        .Add Range:=Selection.Range, Name:="tempqxtz"
        .DefaultSorting = wdSortByName
        .ShowHidden = False
    End With
            
    'Add the Footnote


    ActiveDocument.Footnotes.Add Range:=Selection.Range, Reference:=""
    Selection.Paste
    
    'Return to Main Story


    Selection.GoTo What:=wdGoToBookmark, Name:="tempqxtz"
    
    'Delete the temporary bookmark


    ActiveDocument.Bookmarks("tempqxtz").Delete
 
Bypass:
    
Next oField

MsgBox "Process Complete", vbOKOnly + vbInformation, "Convert In-text Citations to Footnotes"

End Sub

-------------------------------------------